WIP POC MicroShift e2e using robot framework

.gitignore

@@ -6,3 +6,4 @@ _output/*
 _output
 sshfile
 ansible/*.txt
+**/.venv/

e2e-robot/Makefile

@@ -0,0 +1,38 @@
+
+.PHONY: setup dry-run with-filter with-tag all
+
+setup:
+	python3 -m venv .venv && \
+	.venv/bin/python3 -m pip install -r requirements.txt
+
+dry-run:
+	.venv/bin/robot \
+		--dryrun \
+		--outputdir ../_output/e2e-$$(date +'%Y%m%d-%H%M%S') \
+		./tests/microshift.robot
+
+with-filter:
+	.venv/bin/robot \
+		-v USHIFT_IP:$${USHIFT_IP} \
+		-v USHIFT_USER:microshift \
+		--test *router* \
+		--outputdir ../_output/e2e-$$(date +'%Y%m%d-%H%M%S') \
+		-x xunit.xml \
+		./tests/microshift.robot
+
+with-tag:
+	.venv/bin/robot \
+		-v USHIFT_IP:$${USHIFT_IP} \
+		-v USHIFT_USER:microshift \
+		--include smoke \
+		--outputdir ../_output/e2e-$$(date +'%Y%m%d-%H%M%S') \
+		-x xunit.xml \
+		./tests/microshift.robot
+
+all:
+	.venv/bin/robot \
+		-v USHIFT_IP:$${USHIFT_IP} \
+		-v USHIFT_USER:microshift \
+		--outputdir ../_output/e2e-$$(date +'%Y%m%d-%H%M%S') \
+		-x xunit.xml \
+		./tests/microshift.robot

e2e-robot/requirements.txt

@@ -0,0 +1,27 @@
+bcrypt==4.0.1
+certifi==2022.12.7
+cffi==1.15.1
+charset-normalizer==3.1.0
+click==8.1.3
+colorama==0.4.6
+cryptography==40.0.1
+idna==3.4
+Jinja2==3.1.2
+markdown-it-py==2.2.0
+MarkupSafe==2.1.2
+mdurl==0.1.2
+paramiko==3.1.0
+pathspec==0.11.1
+pycparser==2.21
+Pygments==2.14.0
+PyNaCl==1.5.0
+requests==2.28.2
+rich==13.3.3
+rich-click==1.4
+robotframework==6.0.2
+robotframework-requests==0.9.4
+robotframework-sshlibrary==3.8.0
+robotframework-tidy==4.0.1
+scp==0.14.5
+tomli==2.0.1
+urllib3==1.26.15

e2e-robot/tests/microshift.robot

@@ -0,0 +1,167 @@
+*** Settings ***
+Documentation       MicroShift e2e test suite
+
+Library             SSHLibrary
+Library             String
+Library             OperatingSystem
+Library             Process
+Library             RequestsLibrary
+
+Suite Setup         Get Kubeconfig
+Suite Teardown      Remove Kubeconfig
+
+
+*** Variables ***
+${USHIFT_IP}        ${EMPTY}
+${USHIFT_USER}      ${EMPTY}
+
+
+*** Test Cases ***
+Router Smoke Test
+    [Documentation]    Verify that Router correctly exposes HTTP service
+    [Tags]    smoke
+    [Setup]    Run Keywords
+    ...    Create Hello MicroShift Pod    AND
+    ...    Expose Hello MicroShift Pod Via Router    AND
+    ...    Open Port    80    tcp
+
+    Wait Until Keyword Succeeds    3x    3s    Access Hello Microshift via Router
+
+    [Teardown]    Run Keywords
+    ...    Delete Hello MicroShift Pod Route And Service    AND
+    ...    Close Port    80    tcp
+
+Load Balancer Smoke Test
+    [Documentation]    Verify that Load Balancer correctly exposes HTTP service
+    [Tags]    smoke
+    [Setup]    Run Keywords
+    ...    Create Hello MicroShift Pod    AND
+    ...    Expose Hello MicroShift Pod Via LB    AND
+    ...    Open Port    5678    tcp
+
+    Wait Until Keyword Succeeds    3x    3s    Access Hello Microshift via LB
+
+    [Teardown]    Run Keywords
+    ...    Delete Hello MicroShift Pod Route And Service    AND
+    ...    Close Port    5678    tcp
+
+Reboot Test
+    [Documentation]    Verify that MicroShift starts successfully after reboot
+    [Setup]    Run Keywords    Create Pod With PVC
+
+    Open Connection    ${USHIFT_IP}
+    Login    ${USHIFT_USER}    allow_agent=True
+    Execute Command    reboot now    sudo=True
+    Close Connection
+
+    Sleep    15s
+
+    Open Connection    ${USHIFT_IP}
+    Set Client Configuration    timeout=600s
+    Wait Until Keyword Succeeds    10x    10s    Login    ${USHIFT_USER}    allow_agent=True
+
+    Wait Until Keyword Succeeds
+    ...    10x
+    ...    10s
+    ...    Execute Command
+    ...    [ $(systemctl show -p SubState --value microshift) = "running" ]
+    ...    timeout=10s    return_stdout=True    return_stderr=True
+
+    ${stdout}    ${rc}=    Execute Command
+    ...    /etc/greenboot/check/required.d/40_microshift_running_check.sh | tee /tmp/asd.log
+    ...    sudo=True
+    ...    timeout=600s
+    ...    return_stdout=True
+    ...    return_rc=True
+    Log    ${stdout}
+    Should Be Equal As Integers    ${rc}    0
+    Close Connection
+
+    Run With Kubeconfig    oc wait --for=condition=Ready --timeout=120s pod/test-pod
+
+    [Teardown]    Delete Pod With PVC
+
+Failed Test
+    Fail    Let's see how it looks in Prow
+
+
+*** Keywords ***
+Get Kubeconfig
+    [Documentation]    X
+    Open Connection    ${USHIFT_IP}
+    Login    ${USHIFT_USER}    allow_agent=True
+    ${konfig}=    Execute Command
+    ...    cat /var/lib/microshift/resources/kubeadmin/${USHIFT_IP}/kubeconfig
+    ...    sudo=True
+    Should Not Be Empty    ${konfig}
+    ${rand}=    Generate Random String
+    ${path}=    Join Path    /tmp    ${rand}
+    Create File    ${path}    ${konfig}
+    Close Connection
+    Set Suite Variable    \${KUBECONFIG}    ${path}
+
+Remove Kubeconfig
+    Remove File    ${KUBECONFIG}
+
+Access Hello Microshift via Router
+    ${result}=    Run Process
+    ...    curl -i http://hello-microshift.cluster.local --resolve "hello-microshift.cluster.local:80:${USHIFT_IP}"
+    ...    shell=True    timeout=15s
+    Check HTTP Response    ${result}
+
+Access Hello Microshift via LB
+    ${result}=    Run Process    curl -i ${USHIFT_IP}:5678    shell=True    timeout=15s
+    Check HTTP Response    ${result}
+
+Check HTTP Response
+    [Arguments]    ${result}
+    Log    ${result.stdout}
+    Log    ${result.stderr}
+    Should Be Equal As Integers    ${result.rc}    0
+    Should Match Regexp    ${result.stdout}    HTTP.*200
+    Should Match    ${result.stdout}    *Hello MicroShift*
+
+Create Pod With PVC
+    Run With Kubeconfig    oc create -f ../e2e/tests/assets/pod-with-pvc.yaml
+    Run With Kubeconfig    oc wait --for=condition=Ready --timeout=120s pod/test-pod
+
+Delete Pod With PVC
+    Run With Kubeconfig    oc delete -f ../e2e/tests/assets/pod-with-pvc.yaml    True
+
+Create Hello MicroShift Pod
+    Run With Kubeconfig    oc create -f ../e2e/tests/assets/hello-microshift.yaml
+    Run With Kubeconfig    oc wait pods -l app\=hello-microshift --for condition\=Ready --timeout\=60s
+
+Expose Hello MicroShift Pod Via Router
+    Run With Kubeconfig    oc expose pod hello-microshift
+    Run With Kubeconfig    oc expose svc hello-microshift --hostname hello-microshift.cluster.local
+
+Expose Hello MicroShift Pod Via LB
+    Run With Kubeconfig    oc create service loadbalancer hello-microshift --tcp=5678:8080
+
+Delete Hello MicroShift Pod Route And Service
+    Run With Kubeconfig    oc delete route hello-microshift    True
+    Run With Kubeconfig    oc delete service hello-microshift    True
+    Run With Kubeconfig    oc delete -f ../e2e/tests/assets/hello-microshift.yaml    True
+
+Run With Kubeconfig
+    [Arguments]    ${cmd}    ${allow_fail}=False
+    ${result}=    Run Process    ${cmd}    env:KUBECONFIG=${KUBECONFIG}    stderr=STDOUT    shell=True
+    Log    ${result.stdout}
+    IF    ${allow_fail} == False
+        Should Be Equal As Integers    ${result.rc}    0
+    END
+
+Open Port
+    [Arguments]    ${number}    ${protocol}
+    ${res}=    Run Process    bash    -c
+    ...    if declare -F firewall::open_port; then firewall::open_port ${number} ${protocol}; fi    stderr=STDOUT
+    Log    ${res.stdout}
+    Should Be Equal As Integers    ${res.rc}    0
+
+Close Port
+    [Arguments]    ${number}    ${protocol}
+    ${res}=    Run Process    bash    -c
+    ...    if declare -F firewall::close_port; then firewall::close_port ${number} ${protocol}; fi    stderr=STDOUT
+    Log    ${res.stdout}
+    Should Be Equal As Integers    ${res.rc}    0